//First I make a textfield - to display the loaded data.
var TF:TextField = new TextField();
	TF.width  = stage.stageWidth;
	TF.height = stage.stageHeight;
	TF.text	  = "Loading recent tracks...";
	addChild(TF);
 
//Set the location of the XML to load
//Here I'm using my Last.fm recent tracks.
var dataDir:String = "http://ws.audioscrobbler.com/2.0/?method=user.getrecenttracks&user=catfurnace&api_key=b25b959554ed76058ac220b7b2e0a026";
 
//We tell the URLRequest what we want to load -
var xmlString:URLRequest = new URLRequest(dataDir);
//And create a URLLoader to send and load the data -
var xmlLoader:URLLoader = new URLLoader(xmlString);
//We then add a listener to the xmlLoader - which will perform the function "init", when the data has been sent, and the response loaded.
xmlLoader.addEventListener("complete", init);
//We also add a listener to an IO_ERROR event, which will run "xmlLoadFail", if there is an error.
xmlLoader.addEventListener(IOErrorEvent.IO_ERROR, xmlLoadFail);
//So if there is an error - write it in the text box.
function xmlLoadFail(event:IOErrorEvent):void {
	TF.text	  = "Sorry - loading failed  :-( ";
}
 
//This "init" function - which is called if the load request is successful -
function init(event:Event):void {
	trace("loaded xml!");
	//Clear the text box
	TF.text	  = "";
	//Create a new XML document.
	var xDoc:XMLDocument = new XMLDocument();
	//Ignore the white space
	xDoc.ignoreWhite = true;
	var XMLHolder:XML = XML(xmlLoader.data);
	//And parse the data
	xDoc.parseXML(XMLHolder.toXMLString());
 
	//Count how many nodes are in the XML -
	var nodesToLoop:int = Number(xDoc.firstChild.firstChild.childNodes.length);
 
	//For every node in the XML, write the atrist and the track name in the text box.
	for (var j:int = 0; j<nodesToLoop; j++) {
		var artist:String = String(xDoc.firstChild.firstChild.childNodes[j].childNodes[0].firstChild.nodeValue);
		var track:String  = String(xDoc.firstChild.firstChild.childNodes[j].childNodes[1].firstChild.nodeValue);
		//And add this data to the text box
		TF.appendText(artist+" - "+track+"\n")
	}
}